Column with progressive number with xBrowse

[Marco Turco]

Hi all,
I need to display a column with the progressive number in a xBrowse.

I always used the following command with the standard browse:

ADD COLUMN TO oBrw DATA oBrw:nAt() ;
HEADER "Num" SIZE 30 RIGHT

Do you know the equivalent command to make this with xBrowse ?

Thanks.

[nageswaragunupudi]

nArrayAt in xBrowse is the same as nAt of WBrowse.

[anserkk]

How can I achieve the progressive no's while using Recordset (ADO) with xBrowse

I am getting error when I try nArrayAt and nAt

Error Base/1111 Argument Error : Len From ErroSys, Line:0

Code

Code: Select all  Expand view

*-----------------------------------*
FUNCTION connect()
*-----------------------------------*
Local SQL,oBrw
Local oCon := CreateObject('ADODB.Connection')
Local oRecSet := CreateObject( "ADODB.RecordSet" )

oCon:ConnectionString:= "Driver={MySQL ODBC 3.51 Driver};Server=192.168.0.170;Port=3306;Database=MyDataBase;User=MyUser;Password=MyPassword;Option=3;"
TRY
   oCon:Open()
   msgInfo("Connected to Database") 
CATCH oError
   MsgInfo("Connection Failed")
   RETURN(.F.)
END

oRecSet:CursorLocation := adUseClient
oRecSet:LockType := adLockOptimistic
oRecSet:CursorType := adOpenDynamic
oRecSet:Source := "SELECT * FROM ISSUE_TRA WHERE FIN_YEAR=2004"
oRecSet:ActiveConnection(oCon)
oRecSet:Open()

if oRecSet:BOF .AND. oRecSet:EOF
   Msginfo("No Records")
   Return .F.
Endif

oRecSet:MoveFirst()

@0,0 XBROWSE oBrw ;
     OF oWnd ;         
     OBJECT oRecSet;
     LINES CELL

oCol:=oBrw:AddCol()
oCol:cHeader:="No #"
oCol:bStrdata:={ || oBrw:nArrayAt }   // Problem is here

oBrw:CreateFromCode()

RETURN .T.

Regards

Anser

[Armando]

Anser:

Try with oRecSet:AbsolutePosition()

Code: Select all  Expand view

oCol:bStrdata:={ || TRANSFORM(oRecSet:AbsolutePosition(),"@Z 99999") }


:AbsolutePosition() it's like RecNo() in DBF's

Regards

[Daniel Garcia-Gil]

test it...

Code: Select all  Expand view

oCol:bStrData:=GenProgessNumber( oBrw )
....

function GenProgressNumber( oBrw )
return {|| oBrw:nArrayAt }



[anserkk]

Dear Armando

Your solution worked

Code: Select all  Expand view

oCol:bStrdata:={ || TRANSFORM(oRecSet:AbsolutePosition(),"@Z 99999") }

Dear mcfox

your solution did not work and it was giving error

Code: Select all  Expand view

oCol:bStrData:=GenProgessNumber( oBrw )
....

function GenProgressNumber( oBrw )
return {|| oBrw:nArrayAt }


So I changed your code in function GenProgressNumber( oBrw ) to

Code: Select all  Expand view

function GenProgressNumber( oBrw )
return {|| str(oBrw:nArrayAt) }


By adding str I avoided error but the progressive no in the xBrowse is always 0 in all the lines.

Thanks for your help.

I am writing it down here what I have learned and I hope that it may be useful to newbies like me and help them to reduce their learning curve. Time is valuable

So this is how we get a progressive no in xBrowse

IF Array is used in xBrowse then

Code: Select all  Expand view

oCol:bStrData:={ || oBrw:nArrayAt  }

If DBF is used in xBrowse then

Code: Select all  Expand view

oCol:bStrData:={ || str(  RecNo() )   } // I am doubtful here what happens if the DBF is indexed

If RecordSet is used in xBrowse

Code: Select all  Expand view

oCol:bStrdata:={ || TRANSFORM(oRecSet:AbsolutePosition(),"@Z 99999") }
                OR
oCol:bStrdata:={ || str(oRecSet:AbsolutePosition() ) }

Regards

Anser

[Enrico Maria Giordano]

Code: Select all  Expand view

oCol:bStrData:={ || str(  RecNo() )   } // I am doubtful here what happens if the DBF is indexed

You can use OrdKeyNo() instead. But please build indexes with FOR !Deleted() clause or you will have holes in the numbers sequence.

EMG

[anserkk]

Dear EMG

Is there any other way to show a progressive no on xBrowse when used with a DBF other than using OrdKeyNo() with !Delted clause in the index ?

You can use OrdKeyNo() instead. But please build indexes with FOR !Deleted() clause.

Regards

Anser

[Enrico Maria Giordano]

I don't know, sorry.

EMG