Trapping key combinations

[HunterEC]

How can I trap a key combination like, for example: Control-F2, Control-Y ? I had looked at vkeys.ch with no results. Thank you.

[Enrico Maria Giordano]

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oDlg

    LOCAL oGet, cVar := SPACE( 30 )

    DEFINE DIALOG oDlg

    @ 1, 1 GET oGet VAR cVar OF oDlg

    oGet:bKeyDown = { | nKey | Tasti( nKey ) }

    @ 3, 1 BUTTON "&Close" OF oDlg ACTION oDlg:End()

    ACTIVATE DIALOG oDlg;
             CENTER

    RETURN NIL


STATIC FUNCTION TASTI( nKey )

    IF nKey = ASC( "H" ) .AND. GETKEYSTATE( VK_CONTROL )
        ? "CTRL-H"
    ENDIF

    IF nKey = ASC( "Z" ) .AND. GETKEYSTATE( VK_CONTROL )
        ? "CTRL-Z"
    ENDIF

    RETURN NIL

EMG

[HunterEC]

Thank you Enrico. What I'm trying to do is the following:

Code: Select all  Expand view

SETKEY(K_CTRL_Y, {|| SomeStuff()})

Thanks.

[Enrico Maria Giordano]

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oDlg

    LOCAL cVar := SPACE( 30 )

    SETKEY( VK_F2, { || If( GetKeyState( VK_CONTROL ), MsgInfo( "CTRL-F2" ), ) } )
    SETKEY( VK_F3, { || If( GetKeyState( VK_SHIFT ), MsgInfo( "SHIFT-F3" ), ) } )

    DEFINE DIALOG oDlg

    @ 1, 1 GET cVar OF oDlg

    @ 3, 1 BUTTON "&Close" OF oDlg ACTION oDlg:End()

    ACTIVATE DIALOG oDlg;
             CENTER

    RETURN NIL

EMG

[HunterEC]

Enrico:

Thank you very much.