Coordinates Excel-grid.

[Marc Vanzegbroeck]

Hi,

I want to draw some shapes like this in excel (like a bar-graph).


I want the height of the shapes the same of the grid. How can I calculate the coordinates?

[MaxP]

Hi Marc,

try this

Code: Select all  Expand view

#include "Fivewin.ch"

#define msoShapeRectangle       1

FUNCTION MAIN()
        LOCAL   oExcel, oWorkBooks, oSheet, oCell1, oCell2
       
        TRY
                oExcel := TOleAuto():New( "Excel.Application" )
        CATCH
                oExcel := NIL
        END
       
        IF oExcel <> NIL
                oWorkBooks := oExcel:WorkBooks

                IF oWorkBooks <> NIL
                        oWorkBooks:Add()
                        oSheet := oExcel:ActiveSheet                          
                       
                        oCell1 := oSheet:Cells( 4, 2 )
                       
                        oCell2 := oSheet:Cells( 4, 3 )
                       
                        oSheet:Shapes:AddShape( msoShapeRectangle, oCell1:Left, oCell1:Top, oCell1:Width + oCell2:Width, oCell1:Height )
                                               
                        oExcel:Visible := .T.
                ENDIF
        ENDIF
RETURN NIL

Best regards,
Massimo

[Marc Vanzegbroeck]

Thank you Massimo.

It's just what I needed.