Ttitle and Timage problems

[Adolfo]

AS i asked in the spanish forums

I've been trynig with all means, but with bno succes to solve this two problems
Please download the following

http://200.72.140.34/privado/Test.rar

1.- If you move any dialog over the TTITLE, this get erased, Ex. Call the taskmanager and roll it over and see how it dissapears
2.- In menu option TImage, search for a jpg, and see if it gets shown

Tested in 3 Pc's all with XP and 1 without themes

Tested with FWH 907 y 909, with no success
I use xHarbour.org, Borland 5.5.1 and PellesC 6.0

Thanks in advance

From Chile
Adolfo

[ukoenig]

Hello Adolfo,

to many Mistakes, because You are using a MDI-Window, some Changes needed :

Code: Select all  Expand view

#include "FiveWin.ch"
#include "Image.ch"
#include "ttitle.ch"

static oWnd, hDC

//-------------------------------------------------------------------------------------

Function Main()
Local nAncho:=WndWidth(GetDesktopWindow())

DEFINE WINDOW oWnd FROM 1, 1 TO 25, 79 MDI ;
TITLE "Sistema" Menu BuildMenu()


ACTIVATE WINDOW oWnd MAXIMIZED ;
ON INIT W_TITLE( oWnd, nAncho )

Return Nil

// -------------------------------------------------------------------

FUNCTION W_TITLE( oWnd, nAncho )
Local oDlg, oTitle1
Local cTitulo:=( "TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO ")

nDLGStyle = nOR( DS_MODALFRAME | WS_POPUP | WS_VISIBLE | WS_BORDER )
DEFINE DIALOG oDlg SIZE 60, nAncho STYLE nDLGStyle

@ 0,0 TITLE oTitle1 Size nAncho, 60 of oDlg SHADOW SHADOWSIZE 0
oTitle1:aGrdBAck:= { {1,nRGB(251,230,148),nRGB(238,149,21) }}
oTitle1:lRound:=.F.
@  10,  10  TITLETEXT OF oTitle1 TEXT cTitulo COLOR CLR_BLACK

ACTIVATE DIALOG oDlg NOWAIT ;
ON INIT ( oDlg:Move( 50, 0, nAncho, 60,  .f. ) )

RETURN( NIL )

//--------------------------------------------------------------------

Function BuildMenu()
local oMenu

MENU oMenu 2007
MENUITEM "TTitle"
MENU
            MENUITEM "Error de Ttitle"  ACTION MsgAlert("Mover sobre TTitle","Confirme")
ENDMENU
MENUITEM "TImage"
MENU
            MENUITEM "Error de TImage y JPG" ACTION TestImage()
ENDMENU

ENDMENU

Return oMenu

//-----------------------------------------------------------------------

Function TestImage()
Local oDlgTest, oImg1
Local oFoto1:=Space(150)

Define Dialog oDlgTest Resource "IMAGENES"

// RESOURCE "Blanc" = any small BMP-resource
REDEFINE BITMAP oImg1  ID 11  ADJUST  RESOURCE "Blanc"  OF oDlgTest
oImg1:bPainted := {|hDC| DRAW_IMAGE( oImg1, "ZARZAR.JPG" ) }

REDEFINE GET oGet1  VAR oFoto1  ID 101 Of oDlgTest Picture "@K!" ;
VALID ( oImg1:LoadBmp(ALLTRIM(oFoto1)), oImg1:Refresh(), .T.) ;
ACTION ( oFoto1:=cGetFile32("JPEG  | *.jpg |" + "Todos los Archivos | *.* ", ;
"Seleccione imagen",1,"C:\",,.T.), oGet1:refresh()) update

Redefine Button oBtn1 Id 201 of oDlgTest Action oDlgTest:End()

Activate Dialog oDlgTest Centered NOWAIT

Return Nil

// -------------------------------

FUNCTION DRAW_IMAGE( oBitmap, cBitmap)
Local oImage

DEFINE IMAGE oImage FILENAME cBitmap

aRect := GETCLIENTRECT( oBitmap:hWnd )
nBmpWidth := oBitmap:nWidth()
nBmpHeight := oBitmap:nHeight()

PalBmpDraw( oBitmap:GETDC(), 0, 0, oImage:hBitmap, , aRect[4], aRect[3] )
oBitmap:ReleaseDC()

RETURN( NIL )

Best Regards
Uwe

[Adolfo]

UWE...

Thanks...

I'll try it as soon as posible.

[Cgallegoa]

Adolfo,

All you need to do is assign TTitle to oWnd:oWndClient becouse you are using MDI Window:

This works fine:

Code: Select all  Expand view

Function Main()
Local cTitulo:=( "TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO TEXTO ")
Local nAncho:=WndWidth(GetDesktopWindow())

   DEFINE WINDOW oWnd FROM 1, 1 TO 25, 79 MDI ;
   TITLE "Sistema con MDI" Menu BuildMenu()

    @ 70,0 TITLE oTitle1 Size nAncho, 60 of oWnD:oWndClient SHADOW SHADOWSIZE 0
      oTitle1:aGrdBAck:= { {1,nRGB(251,230,148),nRGB(238,149,21) }}
      oTitle1:lRound:=.F.
    @  10,  10  TITLETEXT OF oTitle1 TEXT cTitulo COLOR CLR_BLACK

   ACTIVATE WINDOW oWnd MAXIMIZED

Return Nil

Regards,

Carlos Gallego

[Adolfo]

Carlos, Uwe

Both solutions works fine.
... sorry I completely forgot I was using a MDI Window, my mistake.
.. I guess I'll have to rest some days, I have some faulty IRQ's


Thanks a lot

From Chile
Adolfo