Seek/Search xBrowse Tree

[fraxzi]

Dear All,

How to Seek/Search an Item in xBrowse Tree?


Kind regards,

Frances

[fraxzi]

Dear All,

Not possible? any alternative way?


Kind Regards,

Frances

[nageswaragunupudi]

You need to make your own seek function and set that function to bSeek. In case of trees most likely all the items are not in a sorted order.

I suggest this approach:

Code: Select all  Expand view

oBrw:bSeek := { |c| SeekTree( oBrw, c ) }

//.....
//.....

function SeekTree( oBrw, cSeek )

   local oTree    := oBrw:oTree
   local oFound, oItem := oTree:oFirst
   local lFound   := .f.
   
   cSeek    := Upper( cSeek )

   do while oItem != nil
      if oItem:cPrompt = cSeek
         oFound   := oItem
         exit
      endif
      oItem    := oItem:GetNext()
   enddo
   if oFound != nil
      oBrw:oTreeItem := oFound
      lFound   := .t.
   endif

return lFound


 

[fraxzi]

Dear Mr. RAO,

Thanks for the Input... I did this to make incremental search.. works for me.

Code: Select all  Expand view

oBrw:bSeek := { |c| uSeekTree( oBrw, Upper(c) ) }

...


STATIC FUNCTION uSeekTree( oBrw, cSeek )

 LOCAL oTree  := oBrw:oTree
 LOCAL oFound, oItem := oTree:oFirst
 LOCAL lFound := .F.

 oBrw:cSeek := cSeek

 DO WHILE oItem <> NIL

    IF oBrw:cSeek $ Upper(SubStr(oItem:cPrompt,1,Len(oBrw:cSeek)))
       oFound := oItem
       EXIT
    ENDIF

    oItem := oItem:GetNext()

 ENDDO

 IF oFound <> nil
    oBrw:oTreeItem := oFound
    oBrw:Refresh()
    lFound := .t.
 ENDIF

RETURN lFound
 

Kind Regards,

Frances