get who is using a file

[ukservice]

Hello,

When a folder is shared, is there a function to get all the users that are using a file?.

Thank you.

[anserkk]

I am not sure whether this is what you are looking for. The following code gives you a list of users of a particular exe file.
Try this

Code: Select all  Expand view

#Include "FiveWin.ch"
//-----------------------//
Function Main()
     MsgList(GetExeUsers(cFileName( HB_ARGV( 0 ) )))
Return NIL        
   
*------------------------------------*
FUNCTION GetExeUsers(cExe )
*------------------------------------*
   Local oLoc,oWmi
   Local oList, oProc
   Local cUser, cDomain
   Local aList := {}

   oLoc:= CreateObject( "wbemScripting.SwbemLocator" )
   oWmi:= oLoc:ConnectServer()
   
   IF !Empty(oWmi)
      oList := oWmi:ExecQuery( "select * from Win32_Process where Name = '" + cExe + "'" )
      FOR EACH oProc IN oList
         IF ( oProc:GetOwner( @cUser, @cDomain ) ) == 0
            cUser = cDomain + "\" + cUser
            IF AScan( aList, cUser ) == 0
               AAdd( aList, cUser )
            ENDIF
         ENDIF
      NEXT
   ENDIF

RETURN aList    

Regards
Anser