ButtonBmp - Escape

[FranciscoA]

Friends all,
I have a small issue with the BUTTONBMP buttons and the ESCAPE key in MDI environment using embedded NOWAIT MdiChilds dialogs.
I conditioned the output (oDlg and Child) by GetKeyState (VK_ESCAPE) and it works correctly.
Now if the focus are on any object other than ButtonBmp, the condition works well. But if the user clicks on any ButtonBmp and release the mouse button outside the button, leaving the focus on this, and then press escape, shoots the the escape key action and only closes the dialog, leaving the child active. That is, if any BUTTONBMP has focus and you press the escape key, the given condition with GetKeyState (VK_ESCAPE) is not respected, and only closes the dialog.

Have any of you experienced this problem? Do you have a solution?
I appreciate any comment. I use Fwh1204-xHarbour-PellesC

Greetings.

[ukoenig]

Francisco,
Yes without < oDlg:bKeyDown >, on Btn-focus, the ESC-key didn't work.

You can add :

oDlg:bKeyDown := { | nKey, nFlags | iif( nKey == VK_ESCAPE, oDlg:End(), ) }

A sample
MDI- window => MDI-child => Dialog from MDI-Child ( NOWAIT ) => Dialog from Dialog

Code: Select all  Expand view

#include "FiveWin.ch"

#define COLOR_BTNFACE   15

function Main()
local oWnd, oBar

DEFINE WINDOW oWnd TITLE "MDIChilds" MDI

DEFINE BUTTONBAR oBar _3D OF oWnd

DEFINE BUTTON OF oBar ACTION child(oWnd) //( Child(), MsgInfo( oWnd:oWndClient:aWnd[ 1 ]:cCaption ) )

ACTIVATE WINDOW oWnd maximized

return nil

//----------------------------------------------------------------------------//

function Child(oWnd)
local oDlg, oBtn1, oBtn2, oBtn3
   
DEFINE WINDOW oWndChild MDICHILD OF oWnd ;
FROM 5,5 TO 6,6;
COLOR "N/W" ;
BORDER NONE  NOMAXIMIZE NOMINIMIZE // prevent resizing

oWndChild:bGotFocus  = { || oDlg:SetFocus() }

DEFINE DIALOG oDlg FROM 150, 150 TO 400, 600 ;
OF oWndChild TITLE "Dialog from Child- Window" PIXEL  TRANSPARENT

@ 50, 20 BTNBMP oBtn1 SIZE 50, 20  OF oDlg  2007 ;
CENTER ;
PROMPT "  &Child" ;
ACTION DChild(oDlg)
oBtn1:lTransparent = .t.  

@ 50, 100 BTNBMP oBtn2 SIZE 50, 20 OF oDlg  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )  
oBtn2:lTransparent = .t.                     

@ 80, 100 BTNBMP oBtn3 SIZE 50, 20 OF oDlg  2007 ;
CENTER ;
PROMPT "  &Exit" ;
ACTION oDlg:End()
oBtn3:lTransparent = .t.    

oDlg:bKeyDown := { | nKey, nFlags | iif( nKey == VK_ESCAPE, oDlg:End(), ) }

ACTIVATE DIALOG oDlg NOWAIT

ACTIVATE WINDOW oWndChild

return nil

//---------------------------------------

function DChild(oDlg)
local oDlg1, oBtn4, oBtn5, oBtn6
   
DEFINE DIALOG oDlg1 FROM 300, 300 TO 550, 750  TITLE "Chilf from Dialog " OF oDlg PIXEL  TRANSPARENT
 
@ 20, 20 BTNBMP oBtn4 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )
oBtn4:lTransparent = .t.    

@ 50, 20 BTNBMP oBtn5 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )
oBtn5:lTransparent = .t.    

@ 80, 100 BTNBMP oBtn6 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Exit" ;
ACTION oDlg1:End()
oBtn6:lTransparent = .t.    

ACTIVATE DIALOG oDlg1

return nil
 

Best Regards
Uwe

[FranciscoA]

Dear Uwe,
Your sample works fine, but I had referred to BUTTONBMP, not BTNBMP.
Please take a look at fallowing code.
If a BUTTONBMP has the focus and we press ESCAPE, the dialog closes, but the MDICHILD still open.

I think this behavior comes from the TButton class since TButtonBmp is inherited from that.

With BTNBMP all works fine.

Code: Select all  Expand view

//------------------------------------------------
//PRUEBA 4 MDI + MDICHILD + DIALOG NOWAIT INCRUSTADO + ESCAPE
//-------------------------------------------------

#include "FiveWin.ch"

#define COLOR_BTNFACE   15

//-------------------------------------
function Main()
local oWnd, oBar

DEFINE WINDOW oWnd TITLE "MDIChilds" MDI

DEFINE BUTTONBAR oBar _3D OF oWnd

DEFINE BUTTON OF oBar ACTION child(oWnd)

ACTIVATE WINDOW oWnd maximized

return nil

//----------------------------------------------------------------------------//

function Child(oWnd)
local oWndChild, oDlg, oBtn1, oBtn2, oBtn3, oBtn4
   
DEFINE WINDOW oWndChild MDICHILD OF oWnd ;
FROM 5,5 TO 6,6;
COLOR "N/W" ;
BORDER NONE  NOMAXIMIZE NOMINIMIZE // prevent resizing

oWndChild:bGotFocus  = { || oDlg:SetFocus() }

DEFINE DIALOG oDlg FROM 150, 150 TO 400, 600 STYLE WS_CHILD ;
OF oWndChild TITLE "Dialog from Child- Window" PIXEL  TRANSPARENT


@ 36, 10 SAY "CLASS TBUTTONBMP" OF oDlg PIXEL

@ 50, 10 BUTTONBMP oBtn1 OF oDlg ACTION MsgInfo( "Prueba de Focus" ) ;
         PROMPT "&Test" TEXTRIGHT SIZE 80, 20 PIXEL

@ 80, 10 BUTTONBMP oBtn2 OF oDlg ACTION oDlg:End() ;
         PROMPT "&Exit" TEXTRIGHT SIZE 80, 20 PIXEL



@ 36, 150 SAY "CLASS TBTNBMP" OF oDlg PIXEL

@ 50, 150 BTNBMP oBtn3 SIZE 50, 20 OF oDlg  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )  
oBtn3:lTransparent = .t.                      

@ 80, 150 BTNBMP oBtn4 SIZE 50, 20 OF oDlg  2007 ;
CENTER ;
PROMPT "  &Exit" ;
ACTION oDlg:End()
oBtn4:lTransparent = .t.    

ACTIVATE DIALOG oDlg NOWAIT ;
    VALID if(!GetKeyState(VK_ESCAPE), ( oWndChild:End(), .t. ), .F.) ;
    ON INIT oDlg:Move(0,0)

ACTIVATE WINDOW oWndChild ;
    ON INIT oWndChild:SetSize(oDlg:nWidth,oDlg:nHeight)

return nil
 

Best regards.

[ukoenig]

Francisco,

I will check it and tell You the result

Best Regards
Uwe

[FranciscoA]

Uwe,
Thanks for your attention.

Regards.

[ukoenig]

Francisco,
It works with the changed VALID

ACTIVATE DIALOG oDlg NOWAIT ;
VALID ( oWndChild:End(), .t. ) ;
ON INIT oDlg:Move(0,0)

// VALID if(!GetKeyState(VK_ESCAPE), ( oWndChild:End(), .t. ), .F.)

Best Regards
Uwe

[FranciscoA]

Uwe,
Yes, but the fact is that I want the user can not leave if he uses the key escape.

Best regards.

[ukoenig]

Francisco,

somewhere in the forum there is a function
You can enable / disable the esc-key.

found maybe useful for You :
viewtopic.php?f=3&t=9202&start=0&hilit=disable+esc

Best Regards
Uwe

[FranciscoA]

Uwe,
Thanks. Right now I'm reading the post you say.
Meanwhile, check this out:
viewtopic.php?f=6&t=17845&hilit=escape#p131289
Regards.

[FranciscoA]

Hi Uwe,
I think I found out the solution. Please make the below changes in TButton Class and try the sample.
Please let me know if it is the right way.

Code: Select all  Expand view

//----------------------------------------------------------------------------//

METHOD GetDlgCode( nLastKey ) CLASS TButton

   ::oWnd:nLastKey := nLastKey

/*
   if ::oWnd:oWnd != nil .and. ( ::oWnd:oWnd:IsKindOf( "TFOLDER" ) .or. ;   //Original
                                 ::oWnd:oWnd:IsKindOf( "TFOLDEREX" ) )
       return DLGC_WANTALLKEYS
   endif
*/

  //FranciscoA 21/12/2012
  if ::oWnd:oWnd != nil
      if ::oWnd:oWnd:IsKindOf( "TFOLDER" ) .or. ::oWnd:oWnd:IsKindOf( "TFOLDEREX" )
         return DLGC_WANTALLKEYS
      endif

      if nLastKey == VK_ESCAPE    
         if ::oWnd:IsKindOf( "TDIALOG" )
            return DLGC_WANTALLKEYS
         endif
      endif
  endif

return nil
 

Code: Select all  Expand view

//------------------------------------------------
//PRUEBA 4 MDI + MDICHILD + DIALOG NOWAIT INCRUSTADO + ESCAPE
//-------------------------------------------------

#include "FiveWin.ch"

#define COLOR_BTNFACE   15

//-------------------------------------
function Main()
local oWnd, oBar

DEFINE WINDOW oWnd TITLE "MDIChilds" MDI

DEFINE BUTTONBAR oBar _3D OF oWnd

DEFINE BUTTON OF oBar ACTION child(oWnd)

ACTIVATE WINDOW oWnd maximized

return nil

//----------------------------------------------------------------------------//

function Child(oWnd)
local oWndChild, oDlg, oBtn1, oBtn2, oBtn3, oBtn4
local bExit

 
DEFINE WINDOW oWndChild MDICHILD OF oWnd ;
FROM 5,5 TO 6,6;
COLOR "N/W" ;
BORDER NONE  NOMAXIMIZE NOMINIMIZE // prevent resizing

oWndChild:bGotFocus  = { || oDlg:SetFocus() }

DEFINE DIALOG oDlg FROM 150, 150 TO 400, 600 STYLE WS_CHILD ;
OF oWndChild TITLE "Dialog from Child- Window" PIXEL  TRANSPARENT


@ 36, 10 SAY "CLASS TBUTTONBMP" OF oDlg PIXEL

@ 50, 10 BUTTONBMP oBtn1 OF oDlg ACTION MsgInfo( "Prueba de Focus" ) ;
         PROMPT "&Test" TEXTRIGHT SIZE 80, 20 PIXEL

@ 80, 10 BUTTONBMP oBtn2 OF oDlg ACTION ( oWndChild:End() );
         PROMPT "&Exit" TEXTRIGHT SIZE 80, 20 PIXEL



@ 36, 150 SAY "CLASS TBTNBMP" OF oDlg PIXEL

@ 50, 150 BTNBMP oBtn3 SIZE 50, 20 OF oDlg  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )  
oBtn3:lTransparent = .t.                      

@ 80, 150 BTNBMP oBtn4 SIZE 50, 20 OF oDlg  2007 ;
CENTER ;
PROMPT "  &Exit" ;
ACTION oDlg:End()
oBtn4:lTransparent = .t.    

bExit := {|| MsgInfo("Hello...!!! Do you like music?"+CRLF+;
             "Voyage at the bottom of the bath (The Shadows)") }

ACTIVATE DIALOG oDlg NOWAIT ;
    VALID if(!GetKeyState(VK_ESCAPE), ( oWndChild:End(), .t. ), .F.) ;     //with the tbutton changes, if you not use getkeystate(), valid clause works as normal escape.
    ON INIT oDlg:Move(0,0)

oWndChild:bPostEnd := {|| Eval(bExit) }

ACTIVATE WINDOW oWndChild ;
    VALID .T. ;       //if(!GetKeyState(VK_ESCAPE),(MsgInfo("I go home."), .t.), .F.) ;
    ON INIT oWndChild:SetSize(oDlg:nWidth,oDlg:nHeight)

return nil
 

[ukoenig]

Francisco,

I tested Your changes.
It just disables the ESC-key of the Child-dialog.
Opening a normal Dialog from the Buttonbar or another Dialog
from the Child, the ESC-key still works.



Added :

Code: Select all  Expand view

// a 2. Bar-button

DEFINE BUTTON OF oBar ACTION Dchild(oWnd)

// a new Child-button

@ 10, 80 BTNBMP oBtn1 SIZE 50, 20  OF oDlg  2007 ;
CENTER ;
PROMPT "  &Dialog 2" ;
ACTION DChild(oDlg)
oBtn1:lTransparent = .t.  

//------- 2. Dialog --------------------------------

function DChild(oDlg)
local oDlg1, oBtn4, oBtn5, oBtn6
   
DEFINE DIALOG oDlg1 FROM 300, 300 TO 550, 750  TITLE "Chilf from Dialog " OF oDlg PIXEL  TRANSPARENT
 
@ 20, 20 BTNBMP oBtn4 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )
oBtn4:lTransparent = .t.    

@ 50, 20 BTNBMP oBtn5 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )
oBtn5:lTransparent = .t.    

@ 80, 100 BTNBMP oBtn6 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Exit" ;
ACTION oDlg1:End()
oBtn6:lTransparent = .t.    

ACTIVATE DIALOG oDlg1

return nil
 

Best Regards
Uwe

[FranciscoA]

Uwe,
The goal is to solve why when a ButtonBmp has the focus, the escape key is triggered.
What I mean, is that the goal is not to disable fully the escape key, only somewhere in the code of a program.
Now, about the sample, if you add to your code If (GetKeyState () in the valid clause of the dialog to prevent exiting out, then it will work as we wants.

Code: Select all  Expand view

//------------------------------------------------
//PRUEBA 4 MDI + MDICHILD + DIALOG NOWAIT INCRUSTADO + ESCAPE
//-------------------------------------------------

#include "FiveWin.ch"

#define COLOR_BTNFACE   15

//-------------------------------------
function Main()
local oWnd, oBar

DEFINE WINDOW oWnd TITLE "MDIChilds" MDI

DEFINE BUTTONBAR oBar _3D OF oWnd

DEFINE BUTTON OF oBar ACTION child(oWnd)
DEFINE BUTTON OF oBar ACTION Dchild(oWnd)

ACTIVATE WINDOW oWnd maximized

return nil

//----------------------------------------------------------------------------//

function Child(oWnd)
local oWndChild, oDlg, oBtn0, oBtn1, oBtn2, oBtn3, oBtn4
local bExit

DEFINE WINDOW oWndChild MDICHILD OF oWnd ;
FROM 5,5 TO 6,6;
COLOR "N/W" ;
BORDER NONE  NOMAXIMIZE NOMINIMIZE // prevent resizing

oWndChild:bGotFocus  = { || oDlg:SetFocus() }

DEFINE DIALOG oDlg FROM 150, 150 TO 400, 600 STYLE WS_CHILD ;
OF oWndChild TITLE "Dialog from Child- Window" PIXEL  TRANSPARENT


@ 10, 80 BTNBMP oBtn0 SIZE 50, 20  OF oDlg  2007 ;
CENTER ;
PROMPT "  &Dialog 2" ;
ACTION DChild(oDlg)
oBtn0:lTransparent = .t.


@ 36, 10 SAY "CLASS TBUTTONBMP" OF oDlg PIXEL

@ 50, 10 BUTTONBMP oBtn1 OF oDlg ACTION MsgInfo( "Prueba de Focus" ) ;
         PROMPT "&Test" TEXTRIGHT SIZE 80, 20 PIXEL

@ 80, 10 BUTTONBMP oBtn2 OF oDlg ACTION ( oWndChild:End() );
         PROMPT "&Exit" TEXTRIGHT SIZE 80, 20 PIXEL


@ 36, 150 SAY "CLASS TBTNBMP" OF oDlg PIXEL

@ 50, 150 BTNBMP oBtn3 SIZE 50, 20 OF oDlg  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )  
oBtn3:lTransparent = .t.                      

@ 80, 150 BTNBMP oBtn4 SIZE 50, 20 OF oDlg  2007 ;
CENTER ;
PROMPT "  &Exit" ;
ACTION oDlg:End()
oBtn4:lTransparent = .t.    



bExit := {|| MsgInfo("Hello...!!! Do you like music?"+CRLF+;
             "Voyage at the bottom of the bath (The Shadows)") }

ACTIVATE DIALOG oDlg NOWAIT ;
    VALID if(!GetKeyState(VK_ESCAPE), ( oWndChild:End(), .t. ), .F.) ;
    ON INIT oDlg:Move(0,0)

oWndChild:bPostEnd := {|| Eval(bExit) }

ACTIVATE WINDOW oWndChild ;
    VALID .T. ;    //if(!GetKeyState(VK_ESCAPE),(MsgInfo("I go home."), .t.), .F.) ;
    ON INIT oWndChild:SetSize(oDlg:nWidth,oDlg:nHeight)

return nil


//------- 2. Dialog --------------------------------

function DChild(oDlg)
local oDlg1, oBtn4, oBtn5, oBtn6
   
DEFINE DIALOG oDlg1 FROM 300, 300 TO 550, 750  TITLE "Chilf from Dialog " OF oDlg PIXEL  TRANSPARENT
 
@ 20, 20 BTNBMP oBtn4 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )
oBtn4:lTransparent = .t.    

@ 50, 20 BTNBMP oBtn5 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Focus-test" ;
ACTION MsgAlert( "Focus-test", "Attention" )
oBtn5:lTransparent = .t.    

@ 80, 100 BTNBMP oBtn6 SIZE 50, 20 OF oDlg1  2007 ;
CENTER ;
PROMPT "  &Exit" ;
ACTION  oDlg1:End()
oBtn6:lTransparent = .t.    

ACTIVATE DIALOG oDlg1 ;
   VALID if(!GetKeyState(VK_ESCAPE), .T., .F.)     //<----- here...

return nil
 

Greetings.

[FranciscoA]

Uwe,
I forgot, here's another possible solution
viewtopic.php?f=6&t=25386#p138280

Best regards.

[ukoenig]

Francisco,

tested the valid with some of my tools.
Modal-wnd with dialog-calls
Dialog ( no Window ) with dialog-call
also tested with empty dialogs

I couldn't find any problem and the dialogs with the valid have been blocked of closing, using the ESC-key.

Best Regards
Uwe

[FranciscoA]

Uwe,
Many thanks for your time .

Best regards.