TFont for Antonio

[Otto]

Hello Antonio,
Would you be so kind to adapt the functionality of
METHOD SaveToText( nIndent ).

It would be fine having similar functions like
METHOD SaveState( aData )
METHOD RestoreState( cInfo ) in xBrowse
for TFont class.

Thanks in advance
Otto

[Silvio.Falconi]

Otto,
I save the font of mine xbrowses on file Ini

I create a setup for colums,background and fonts Ican call on each table(xbrowse) :




For the fonts then I save on file ini

Sample :
[FntBrowse]
mvBrwFont=Forte:10:Normale;Elephant:10:Normale;Engravers MT:10:Normale;




and then on xbrowse I call the fonts at init for Head,Dataa and Footers


Do you like it ?

[Otto]

Hello Silvio,
this question is about TFont.

But please post you code. I am sure it is useful for many of us.

Best regards,
Otto

[nageswaragunupudi]

Mr Otto

Can you pls try these two functions?

Code: Select all  Expand view

//----------------------------------------------------------------------------//

function FontToText( oFont )
return FW_ValToExp(  { ;
   oFont:cFaceName, 0, oFont:nInpHeight, .f., oFont:lBold, oFont:nEscapement, ;
   oFont:nOrientation, nil, oFont:lItalic, oFont:lUnderline, oFont:lStrikeOut, ;
   oFont:nCharSet, oFont:nOutPrecision, oFont:nClipPrecision, oFont:nQuality, ;
   nil, oFont:nPitchFamily }  )
//----------------------------------------------------------------------------//

function FontFromText( cText )
return HB_ExecFromArray( TFont(), "NEW", &cText )

//----------------------------------------------------------------------------//
 

[Otto]

Dear Mr. Rao,
thank you for helping me.

If I read the Font from the restored value the result differ from the original Font. I did many tests this afternoon also with the build in method cGenPrg with the same result.
Please see the screen shot.
The height is not like the original.

Best regards,
Otto











This is my test program

Code: Select all  Expand view

#include "FiveWin.ch"

 Function Main()

    LOCAL oWnd, oSay, cVar
    //LOCAL oFont := TFont():New( 'Calibri', 15.40, 35, .f., .f., 0, 0, 400, .f., .f., .f., 0,3, 2, 1,, 34 )
    LOCAL oFont
    local cText := memoread("RAOfont.txt")
 
    oFont := FontFromText( cText )
 
 
 
 msginfo( "RAOfont.txt" )
 
 //oFont := TFont():New( {"Calibri",0,24,.F.,.F.,0,0,,.F.,.F.,.F.,0,3,2,1,,34} )
 
 DEFINE WINDOW oWnd;
       FROM 1,5 TO 20,65;
       TITLE "Test font. oSay:oFont:lBold is always .t.!"

           @ 12,10 ;
         SAY oSay ;
      PROMPT "ABC Is this bold now?" ;
          OF oWnd ;
        FONT oFont ;
        SIZE 200, 100



 @ 2,10 BUTTON "SelFont";
       SIZE 100,50;
       ACTION oSay:SelFont() OF oWnd

 @ 2,40 BUTTON "cGenPrg";
       SIZE 100,50;
       ACTION ( cVar := oSay:oFont:cGenPrg( cVar ),memowrit("font.txt",cVar) ) OF oWnd

 
  @ 5,40 BUTTON "FontToText";
       SIZE 100,50;
       ACTION (cVar := FontToText( oFont ),memowrit( "RAOfont.txt",cVar) ) OF oWnd
 
 
 ACTIVATE WINDOW oWnd

 RETU NIL
 
 
//----------------------------------------------------------------------------//

function FontToText( oFont )
return FW_ValToExp(  { ;
   oFont:cFaceName, 0, oFont:nInpHeight, .f., oFont:lBold, oFont:nEscapement, ;
   oFont:nOrientation, nil, oFont:lItalic, oFont:lUnderline, oFont:lStrikeOut, ;
   oFont:nCharSet, oFont:nOutPrecision, oFont:nClipPrecision, oFont:nQuality, ;
   nil, oFont:nPitchFamily }  )
//----------------------------------------------------------------------------//

function FontFromText( cText )
return HB_ExecFromArray( TFont(), "NEW", &cText )

//----------------------------------------------------------------------------//
 
 

[nageswaragunupudi]

I am using this program to check:

Code: Select all  Expand view

#include "FiveWin.Ch"
#include "hbcompat.ch"
#include "xbrowse.ch"

//----------------------------------------------------------------------------//

function Main()

   local oDlg, oBrw, oTestFont, oCopyFont, oOldFont, cFontText

   DEFINE FONT oTestFont FROM USER
   cFontText   := FontToText( oTestFont )
   if File( 'FONTSAVE.TXT' )
      oOldFont := FontFromText( MemoRead( 'FONTSAVE.TXT' ) )
   endif
   MsgInfo( cFontText )
   oCopyFont   := FontFromText( cFontText )
   MEMOWRIT( 'fontsave.txt', cFontText )

   DEFINE DIALOG oDlg SIZE 500,300 PIXEL
   @ 10,10 XBROWSE oBrw SIZE -10,-10 PIXEL OF oDlg ;
      DATASOURCE { 'One', 'Two', Date(), 234.56, 'Three', 'Four' } ;
      COLUMNS 1, 1, 1 HEADERS "SELFONT", "COPYFONT", "OLDFONT" CELL LINES NOBORDER

   WITH OBJECT oBrw
      :aCols[ 1 ]:oDataFont   := oTestFont
      :aCols[ 2 ]:oDataFont   := oCopyFont
      if oOldFont != nil
         :aCols[ 3 ]:oDataFont   := oOldFont
      endif
      //
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oTestFont, oCopyFont
   if oOldFont != nil
      RELEASE FONT oOldFont
   endif

return (0)

//----------------------------------------------------------------------------//
function FontToText( oFont )
return FW_ValToExp(  { ;
   oFont:cFaceName, 0, oFont:nInpHeight, .f., oFont:lBold, oFont:nEscapement, ;
   oFont:nOrientation, nil, oFont:lItalic, oFont:lUnderline, oFont:lStrikeOut, ;
   oFont:nCharSet, oFont:nOutPrecision, oFont:nClipPrecision, oFont:nQuality, ;
   nil, oFont:nPitchFamily }  )
//----------------------------------------------------------------------------//
function FontFromText( cText )
return HB_ExecFromArray( TFont(), "NEW", &cText )
//----------------------------------------------------------------------------//
 

[Otto]

Dear Mr. Rao,
thank you. Your code is working fine.
I had a mistake here.
FontToText( oSay:oFont )
@ 5,40 BUTTON "FontToText";
SIZE 100,50;
ACTION (cVar := FontToText( oFont ),memowrit( "RAOfont.txt",cVar) ) OF oWnd

But I still have a different behaviour with the build in class oFont:cGenPrg().

with build in:
oFont := TFont():New( 'Verdana', 21.12, 48, .f., .f., 0, 0, 400, .f., .f., .f., 0,3, 2, 1,, 34 )
with your code and this gives the correct behaviour if you use FontFromText( cText )
{"Verdana", 0,-48, .F., .F., 0, 0, , .F.,.F.,.F.,0,3,2,1,,34}

Best regards,
Otto

[nageswaragunupudi]

Please modify this line method cGenPrg

Code: Select all  Expand view

     cCode    += "'" + ::cFaceName + "', " + nTrim( ::nwidth ) + ", " + nTrim( ::nHeight ) + ", .f., "
 

as

Code: Select all  Expand view

      cCode    += "'" + ::cFaceName + "', " + nTrim( ::nInpwidth ) + ", " + nTrim( ::nInpHeight ) + ", .f., "
 

[Otto]

Dear Mr. Rao,
this is the output of your file:
{"Calibri", 0, -19, .F., .F., 0, 0, , .F., .F., .F., 0,3, 2, 1, ,34}
This of method cGenPrg:
'Calibri', 0, -19, .f., .f., 0, 0, 400, .f., .f., .f., 0,3, 2, 1, , 34 )
There is a difference in one value.
I think this value is ::nWeight .
Best regards,
Otto

[nageswaragunupudi]

Yes. :nInpWidth and :nWeight
I revised the function too

Code: Select all  Expand view

//----------------------------------------------------------------------------//
function FontToText( oFont )
return FW_ValToExp(  { ;
   oFont:cFaceName, oFont:nInpWidth, oFont:nInpHeight, .f., oFont:lBold, oFont:nEscapement, ;
   oFont:nOrientation, oFont:nWeight, oFont:lItalic, oFont:lUnderline, oFont:lStrikeOut, ;
   oFont:nCharSet, oFont:nOutPrecision, oFont:nClipPrecision, oFont:nQuality, ;
   nil, oFont:nPitchFamily }  )
//----------------------------------------------------------------------------//
function FontFromText( cText )
return HB_ExecFromArray( TFont(), "NEW", &cText )
//----------------------------------------------------------------------------//
 

Now, these functions and also cGenPrg method of oFont should work reliably