Detect Memo Field

[Silvio.Falconi]

If I have a xbrowse and wish see (or edit) a Memo Field How I can Make ?
First I must see if there is a Memo Field and then iI can open a Dialog with a get ..Memo
How I can detect if on fields of xbrowse column there is or there memo fields ?

[ADutheil]

Code: Select all  Expand view

FUNCTION ChkForMemo( cAlias )
LOCAL aStru := ( cAlias )->( dbStruct() )
LOCAL lRetu := .F.

aEval( aStru, { | x | if( x[ 2 ] == "M", lRetu := .T., ) } )
RETURN ( lRetu )

[ukoenig]

Silvio,

there is a sample : xBrMemo.prg

Best Regards
Uwe

[nageswaragunupudi]

How I can detect if on fields of xbrowse column there is or there memo fields ?

oCol:cDataType

Note: If you create xbrowse with full command syntax.

[Silvio.Falconi]

Sorry ,
Thank ADutheil
Now I Know the dbf have the memo field but I canno Know the name of this or these fileds to edit

but I not Know wich i s the name of the field(s) Memo

Ihave a xbrowse with

....
@ 0, 0 XBROWSE oBrwLook OF oDlgLook SIZE -1,-20 PIXEL ;
DATASOURCE cdbf ;
COLUMNS aFields HEADERS aNames COLSIZES aSizes

for n := 1 to Len( oBrwLook:aCols )
if oBrwLook:aCols[ n ]:cDataType == 'M'
oBrwLook:aCols[ n ]:bStrData = GenLocalBlock( oBrwLook:aCols, n )
endif
next
....

function GenLocalBlock( aCols, n )
return { || If( Empty( Eval( aCols[ n ]:bEditValue ) ), "<memo>", "<Memo>" ) }

I see the column with the text " Memo"


then from a toolbar I wish edit all memo field on this table
I made :
static function VistaMemo(oBrwLook,cDbf)
IF ChkForMemo( cDbf ) // function of ADutheil

//edit Memo
// If I have two fields type memo I must use a combobox to select the field or I can edit the fied Memo with as xBrMemo.prg

Endif
Return nil

[ADutheil]

You can modify the function ChkForMemo to return an array to populate your combobox

Code: Select all  Expand view

FUNCTION ChkForMemo( cAlias )
LOCAL aStru := ( cAlias )->( dbStruct() )
LOCAL aMemo := {}

aEval( aStru, { | x | if( x[ 2 ] == "M", aAdd( aMemo, x[ 1 ] ) , ) } )
RETURN ( aMemo )
 

[Silvio.Falconi]

ok but how I can set the field from combobox to edit that field
I explain I must set cNotes:=cdbf->namefieldMemo

@ 10,25 COMBOBOX oCbx VAR cCbx ITEMS aCampiMemo;
SIZE 80,50 PIXEL OF oDlg STYLE CBS_DROPDOWN ;
ON CHANGE cNotes:=(cDbf)-> ?


see the test
static function VistaMemo(oBrwLook,cDbf)
Local aCampiMemoTitle:= {}
Local aCampiMemo:= ChkForMemo( cDbf )
Local oCbx,cCbx
local oGet,cnotes


IF len(aCampiMemo)>0
DEFINE DIALOG oDlg SIZE 400,200 PIXEL TITLe "Vista Memo"
@ 10,5 SAY "Tipo:" SIZE 40,10 PIXEL OF oDlg
@ 10,25 COMBOBOX oCbx VAR cCbx ITEMS aCampiMemo;
SIZE 80,50 PIXEL OF oDlg STYLE CBS_DROPDOWN ;
ON CHANGE cNotes:=(cDbf)->&nAt

@ 24,25 GET oGet VAR cNotes TEXT SIZE 80,40 PIXEL OF oDlg
ACTIVATE DIALOG oDlg center
ENDIF

RETURN NIL


FUNCTION ChkForMemo( cAlias )
LOCAL aStru := ( cAlias )->( dbStruct() )
LOCAL aMemo := {}

aEval( aStru, { | x | if( x[ 2 ] == "M", aAdd( aMemo, x[ 1 ] ) , ) } )
RETURN ( aMemo )

[ADutheil]

Code: Select all  Expand view

STATIC FUNCTION VistaMemo(oBrwLook,cDbf)
Local aCampiMemoTitle:= {}
Local aCampiMemo:= ChkForMemo( cDbf )
Local oCbx,cCbx
local oGet,cnotes


IF len(aCampiMemo)>0
    DEFINE DIALOG oDlg SIZE 400,200 PIXEL TITLe "Vista Memo"
    @ 10,5 SAY "Tipo:" SIZE 40,10 PIXEL OF oDlg
    @ 10,25 COMBOBOX oCbx VAR cCbx ITEMS aCampiMemo SIZE 80,50 PIXEL OF oDlg STYLE CBS_DROPDOWN ON CHANGE (cNotes:= GetMemo( cDbf, cCbx ), oGet:Refresh() )

    @ 24,25 GET oGet VAR cNotes TEXT SIZE 80,40 PIXEL OF oDlg
    ACTIVATE DIALOG oDlg center
ENDIF

RETURN NIL

STATIC FUNCTION ChkForMemo( cAlias )
LOCAL aStru := ( cAlias )->( dbStruct() )
LOCAL aMemo := {}

aEval( aStru, { | x | if( x[ 2 ] == "M", aAdd( aMemo, x[ 1 ] ) , ) } )
RETURN ( aMemo )

STATIC FUNCTION GetMemo( cDbf, cCbx )
RETURN (cDbf)->(&cCbx)

[Antonio Linares]

Silvio,

FWH samples/fivedbu.prg automatically detects a memo field and offers its edition