Folderex Gracent

[D.Fernandez]

Hola señores.

Tengo un FolderEx asi:

Code: Select all  Expand view  RUN

REDEFINE FOLDEREX oFolder ID 110  OF oDlgFolder ;
            PROMPT " Datos de la Empresa", "  Conf. Impresión  ", " Configurar permisos " ;
            DIALOGS "1FOLD1",  "1FOLD2", "1FOLD3"  BRUSH oBrush
            oFolder:SetFont(oFont0)

Desearía darle un gradiente a cada uno de los dialogos PAGE1 PAGE2 PAGE3
Me dan una idea por favor?

Gracias. Saludos

Ruben Dario Fernandez

[cmsoft]

Ruben, puedes ponerle gradiente en el FOLDER y tambien a cada dialogo que incluyes en cada opcion del FOLDER

Code: Select all  Expand view  RUN

#include "Fivewin.ch"
Function Main()
LOCAL oDlg1, oFld, oFont, oBrush, oGet := ARRAY (4), oBot := ARRAY(2), aVar := ARRAY(4), lRta := .f.
afill(aVar, space(10))

DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-11.5
DEFINE BRUSH oBrush GRADIENT { { 3, RGB( 237, 242, 248 ), RGB( 0, 5, 3 ) } } HORIZONTAL  //Aqui le das el gradiente al Dialogo que contiene el FOLDER
DEFINE DIALOG oDlg1 RESOURCE "PARAMETROS" BRUSH oBrush TRANSPARENT
oDlg1:lHelpIcon := .f.
REDEFINE FOLDEREX oFld ID 100 OF oDlg1 ;
        ITEMS " Datos de la Empresa", "  Conf. Impresión  ", " Configurar permisos ";
        PAGES "1FOLD1",  "1FOLD2", "1FOLD3" ;
        OPTION 1 ;
        ROUND 3

   //PESTAÑA 1 ---- DATOS GENERALES
     REDEFINE GET oGet[1] VAR aVar[1]     OF oFld:aDialogs[1] ID 101 PICTURE "@!"
     
    //PESTAÑA 2 ---- DATOS DE LA VENTA
     REDEFINE GET oGet[2] VAR aVar[2]   OF oFld:aDialogs[2] ID 101
     

    //PESTAÑA 3 ---- DATOS DE PAGO A PROVEEDORES
     REDEFINE GET oGet[3] VAR aVar[3]  OF oFld:aDialogs[3] ID 101
     
     REDEFINE BUTTON oBot[1] ID 201 OF oDlg1 ACTION ((lRta := .t.), oDlg1:End() )
     REDEFINE BUTTON oBot[2] ID 202 OF oDlg1  CANCEL ACTION ((lRta := .f.), oDlg1:End() )

oFld:aDialogs[1]:Gradient( { { 1, RGB( 236,  90, 128 ), RGB( 236, 150, 136 ) } } )  // Gradiente Dialogo 1 dentro del folder
oFld:aDialogs[2]:Gradient( { { 1, RGB( 100, 180, 228 ), RGB( 100, 242, 238 ) } } )  // Gradiente Dialogo 2 dentro del folder
oFld:aDialogs[3]:Gradient( { { 1, RGB( 200, 240, 100),  RGB( 200, 242, 138 ) } } )  // Gradiente Dialogo 3 dentro del folder

ACTIVATE DIALOG oDlg1 CENTER
return nil
 

Espero te sirva

[karinha]

Puedes hacerlo con BRUSH también:

Code: Select all  Expand view  RUN

   // Brush no Folder
   FOR nI := 1 TO LEN( oFld:aDialogs )

      oFld:aDialogs[nI]:SetBrush( oBrush )
      oFld:aDialogs[ nI ]:Refresh()

   NEXT
 

Regards, saludos.

[D.Fernandez]

Excelente, excelente.

Muchas gracias.

Saludos
Ruben Dario Fernandez

(No conteste antes porque no estaba)