aEval( oMenu:aItems ) ?? ( Now It's Ok! )

[JC]

Antonio and friends,

Why this source code not works? Exists a workarea open into cAlias!

Code: Select all  Expand view

MENU oMenu POPUP

     MENUITEM "Test One"   ACTION msgIngo( "Test One" )
     SEPARATOR
     MENUITEM "Test Two"   ACTION msgIngo( "Test Two" )
     MENUITEM "Test Three" ACTION msgIngo( "Test Three" )

     aEval( oMenu:aItems, {|oItem| oItem:bWhen := {|| !( ( cAlias )->( lastRec() ) == 0 ) } } )

ENDMENU

[Daniel Garcia-Gil]

put outside MENU/ENDMENU

Code: Select all  Expand view

MENU oMenu POPUP

     MENUITEM "Test One"   ACTION msgIngo( "Test One" )
     SEPARATOR
     MENUITEM "Test Two"   ACTION msgIngo( "Test Two" )
     MENUITEM "Test Three" ACTION msgIngo( "Test Three" )

ENDMENU

aEval( oMenu:aItems, {|oItem| oItem:bWhen := {|| !( ( cAlias )->( lastRec() ) == 0 ) } } )


[JC]

Daniel,

Your tip don't works!

[Antonio Linares]

Julio,

Place a MsgBeep() there to check if the code is properly evaluated:

Code: Select all  Expand view

aEval( oMenu:aItems, {|oItem| oItem:bWhen := {|| MsgBeep(), !( ( cAlias )->( lastRec() ) == 0 ) } } )


Has cAlias a right value ?

[JC]

Antonio,

cAlias is "ENT" and "ENT" is a workarea open to my sql result... when I try ( cAlias )->( browse() ), the command show me the rows.

And yes, I tried to use a msginfo( "test" ) in the same place, but still not works!

Code: Select all  Expand view

MENU oMenu POPUP

     MENUITEM "Test One"   ACTION msgIngo( "Test One" )
     SEPARATOR
     MENUITEM "Test Two"   ACTION msgIngo( "Test Two" )
     MENUITEM "Test Three" ACTION msgIngo( "Test Three" )

     aEval( oMenu:aItems, {|oItem| msgInfo( "test" ), oItem:bWhen := {|| !( ( cAlias )->( lastRec() ) == 0 ) } } )

ENDMENU

Outch!

[JC]

Just to up

[Antonio Linares]

As Daniel told you, you have to call AEval() after ENDMENU

[JC]

As Daniel told you, you have to call AEval() after ENDMENU

Antonio,

Ok, but I already tried that! Simply does not work!
I have tried with menu "non popup" and work very fine!

[Antonio Linares]

Julio,

Here you have a working example. Please keep in mind that the WHEN expression is evaluated when the menu is going to be created.

Code: Select all  Expand view

#include "FiveWin.ch"

function Main()

   local oWnd

   DEFINE WINDOW oWnd
   
   ACTIVATE WINDOW oWnd ;
      ON RIGHT CLICK ShowPopup( nRow, nCol, oWnd )

return nil

function ShowPopup( nRow, nCol, oWnd )

   local oPopup
   
   static n := 1

   MENU oPopup POPUP 2007
      MENUITEM "One"   WHEN n++ % 2 == 0
      MENUITEM "Two"   WHEN n++ % 2 == 0
      MENUITEM "Three" WHEN n++ % 2 == 0
   ENDMENU   

   ACTIVATE POPUP oPopup WINDOW oWnd AT nRow, nCol

return nil


[JC]

I have this situation:


Taking into account is that when a block of code, a refresh would not be doing the upgrade of code at "!( ( cAlias )->( lastRec() ) == 0 )" ?

When the number of registers is 0 (zero), the button "Operações" with a menu popup need to be disabled!

Even after they have created? Or not!?

[Antonio Linares]

oBtnOperaciones:bWhen := { || ! ( ( cAlias )->( lastRec() ) == 0 ) }

[JC]

Antonio,

I've done this, thank you!

However, there are two menu items that need to be empowered independent of the situation, I only not have put in the example.

Exists another way to do it automatically??

[Antonio Linares]

Júlio,

This change is required in Class TMenu Method Activate()

Code: Select all  Expand view

      ...
      oWnd:oPopup = Self
      ::Initiate()   // New !!!

      TrackPopup( ::hMenu, 2, aPoint[ 1 ], aPoint[ 2 ], 0, oWnd:hWnd )
      ...


With that change, this example works fine:

Code: Select all  Expand view

#include "FiveWin.ch"

function Main()

   local oWnd, oBtn

   DEFINE WINDOW oWnd

   @ 3, 3 BTNBMP oBtn OF oWnd SIZE 80, 25
   
   oBtn:oPopup = BuildMenu()
   
   ACTIVATE WINDOW oWnd

return nil

function BuildMenu()

   local oPopup
   
   static n := 1

   MENU oPopup POPUP 2007
      MENUITEM "One"   WHEN n++ % 2 == 0
      MENUITEM "Two"   WHEN n++ % 2 == 0
      MENUITEM "Three" WHEN n++ % 2 == 0
   ENDMENU   

return oPopup


[JC]

Antonio,

Now works fine!
Thank you.