How to set Date ( SOLVED )

[fafi]

Hi ! Friends

How to set date format in DD/MM/YYYY for DTPICKER class ..

Code: Select all  Expand view

#include "FiveWin.ch"
#include "dtpicker.ch"

FUNCTION Main()

   local oWnd, oSay
   local dDate

   set date british
   set century on


   dDate := Date()

   DEFINE WINDOW oWnd TITLE "DTPicker from code ...."

   @ 2, 2 DTPICKER dDate OF oWnd ON CHANGE If( oSay != nil, oSay:Refresh(),) // not work MM/DD/YYYY

   @ 3, 30 SAY oSay PROMPT "Date: "+ Dtoc( dDate ) OF oWnd SIZE 200, 20 // work here DD/MM/YYYY

   @ 6, 2 BUTTON "From resources ..." OF oWnd ACTION FromRes( oWnd ) SIZE 150, 30

   ACTIVATE WINDOW oWnd

return nil

FUNCTION FromRes( oWnd )

   local oDlg, oSay
   local dDate := Date()

   DEFINE DIALOG oDlg RESOURCE "DTPTEST"

   REDEFINE DTPICKER dDate ID 101 OF oDlg ;
      ON CHANGE oSay:Refresh()

   REDEFINE SAY oSay PROMPT "Date: "+ Dtoc(dDate) ID 102 OF oDlg

   ACTIVATE DIALOG oDlg CENTERED

return nil

procedure AppSys  // Xbase++ requirement

return

 

Not work..
get DTPICKER always display MM/DD/YYYY

Thanks for help

Regards
Fafi

[ukoenig]

Hello Fafi,

have a look at the TRANSFORM - Function.

SET DATE BRITISH
dDate := TRANSFORM( DATE(), @D ) // Shows the Date-Format, defined in SET DATE
Result : 03/05/09

Regards
Uwe

[fafi]

Hello Fafi,

have a look at the TRANSFORM - Function.

SET DATE BRITISH
dDate := TRANSFORM( DATE(), @D ) // Shows the Date-Format, defined in SET DATE
Result : 03/05/09

Regards
Uwe

Still not work.. please compile my source code above..

Regards
Fafi

[frose]

Hello fafi,

The object ‘TDatePick’ uses the date format from the system!

[Silvio]

STAT FUNC Set_Date()
LOCAL oDlg, oGet, lChg:=.F.
LOCAL dDate:=Date()
DEFINE DIALOG oDlg RESOURCE "SET_DATE" FONT oApp:oFont
REDEFINE DTPICKER oGet VAR dDate ID 10 OF oDlg ;
ON CHANGE oGet:Refresh()
REDEFINE BUTTON ID 20 OF oDlg ACTION (lChg:=.T.,oDlg:End())
REDEFINE BUTTON ID 30 OF oDlg ACTION (lChg:=.F.,oDlg:End()) CANCEL
ACTIVATE DIALOG oDlg
IF lChg
SetDate(Day(dDate),Month(dDate),Year(dDate))
ENDIF
RETURN (NIL)

[nageswaragunupudi]

In your code, immediately after the line

Code: Select all  Expand view

@ 2, 2 DTPICKER dDate OF oWnd ON CHANGE If( oSay != nil, oSay:Refresh(),)

include this code

Code: Select all  Expand view

SendMessage( ATail( oWnd:aControls ):hWnd, 4101, 0, StrTran( lower( Set( _SET_DATEFORMAT ) ), 'mm', 'MM' ) )

Now dtpicker will show the date in whatever the DATEFORMAT is Set.

[fafi]

Thanks Mr. Rao..

It's work

Code: Select all  Expand view

#include "FiveWin.ch"
#include "dtpicker.ch"

FUNCTION Main()

   local oWnd, oSay
   local dDate

   set date british
   set century on


   dDate := Date()

   DEFINE WINDOW oWnd TITLE "DTPicker from code ...."

   @ 2, 2 DTPICKER dDate OF oWnd ON CHANGE If( oSay != nil, oSay:Refresh(),) // not work MM/DD/YYYY

   SendMessage( ATail( oWnd:aControls ):hWnd, 4101, 0, StrTran( lower( Set( _SET_DATEFORMAT ) ), 'mm', 'MM' ) )


   @ 3, 30 SAY oSay PROMPT "Date: "+ Dtoc( dDate ) OF oWnd SIZE 200, 20 // work here DD/MM/YYYY

   @ 6, 2 BUTTON "From resources ..." OF oWnd ACTION FromRes( oWnd ) SIZE 150, 30

   ACTIVATE WINDOW oWnd

return nil

FUNCTION FromRes( oWnd )

   local oDlg, oSay
   local dDate := Date()

   DEFINE DIALOG oDlg RESOURCE "DTPTEST"

   REDEFINE DTPICKER dDate ID 101 OF oDlg ;
      ON CHANGE oSay:Refresh()

   REDEFINE SAY oSay PROMPT "Date: "+ Dtoc(dDate) ID 102 OF oDlg

   ACTIVATE DIALOG oDlg CENTERED

return nil

procedure AppSys  // Xbase++ requirement

return

 

Many thanks again..

Regards
Fafi

[frose]

Rao,

thank you very much for this piece of code.

For better understanding, I've searched the forum and found this thread: viewtopic.php?f=3&t=8249

Antonio wrotes:

We will wait to get some feedback from users before implementing it in the Class.

So for me it is only logic, to change the behavior of the datepicker control to use the date format of the app!