How to override DATA in the FW class?

[dutch]

Dear All,

I would like to change DATA in TGET classes. I don't need to change original FIVEHX.LIB, because I don't want to worry about FW upgrade version.

::lTransparent := .T. // for default transparent say

Regards,
Dutch

[ukoenig]

Hello Dutch,

Use the prg-file of the class, You want to change something.
Include the modified Prg ( Class ) in You Link RMK-File.
The included Prg will replace the Prg from the Lib.
Using the original Lib again, delete the file from the RMK.

Best Regards
Uwe

[Adolfo]

Would be nice to know how to do it without cahnging the Libs, or adding modified prgs..

For instance to change CLASSDATA lClrFocus in Tget Class

From Chile
Adolfo

[Marcelo Via Giglio]

hello,

maybe this topic cam be usefull

http://forums.fivetechsupport.com/viewtopic.php?f=6&t=14432&p=74648&hilit=extend#p74648

regards

Marcelo

[StefanHaupt]

Adolfo,

you can try to replace the New() method

Code: Select all  Expand view

OVERRIDE METHOD New IN CLASS TGET WITH MyNew

STATIC FUNCTION MyNew

LOCAL Self := HB_QSelf()

  <your code>

RETURN (Self)

and write your own method, where you can set all default parameters you want.

[dutch]

Dear Stefan,

I can override class now but the case that I mention is override CLASSDATA in the CLASS as first Post Example. Because I need only change one DATA. If Override Method, It means to maintain this override class and every version.

Regards,
Dutch

[Antonio Linares]

Adolfo,

You can do it this way:

Code: Select all  Expand view

   TGet():SetColorFocus( nRGB( 200, 120, 120 ) )
 

Please notice that we don't really create a GET control, as we don't call New() or Redefine() methods

[Antonio Linares]

Dutch,

Here you have a working example:

Code: Select all  Expand view

#include "FiveWin.ch"

function Main()

   local oDlg

   // Just call it ONCE in your application!
   AddClassData( TSay(), "lTransparent", .T. ) // .T. -> initial value

   DEFINE DIALOG oDlg TITLE "Test" COLOR "W/B"

   @ 1, 2 SAY "Hello" COLOR "R/BG+"

   @ 2, 2 SAY "World!" COLOR "R/GR+"

   ACTIVATE DIALOG oDlg CENTERED

return nil

function AddClassData( oObj, cClsData, uVal )

   local hClass := oObj:ClassH

   __clsAddMsg( hClass, cClsData, __CLS_CNTCLSDATA( hClass ) + 1,;
                HB_OO_MSG_CLSACCESS, uVal, HB_OO_CLSTP_EXPORTED )  

   __clsAddMsg( hClass, "_" + cClsData, __CLS_CNTCLSDATA( hClass ) + 1,;
                HB_OO_MSG_CLSASSIGN,, HB_OO_CLSTP_EXPORTED )  
               
return nil  
 

[StefanHaupt]

Dutch,

I can override class now but the case that I mention is override CLASSDATA in the CLASS as first Post Example. Because I need only change one DATA. If Override Method, It means to maintain this override class and every version.

Regards,
Dutch

If you override a method this is valid for your application, you can copy and paste the original method and only change the data you need. Antonio´s solution is more simple and flexible, but it is also valid for every call of this class in your application.

If you need to change the DATA only in certain situations, you have to create a new class that inherits from the original one.

[Otto]

Antonio,
could you please post the values for:
HB_OO_MSG_CLSACCESS, uVal, HB_OO_CLSTP_EXPORTED
Thanks in advance
Otto

[StefanHaupt]

Otto,

in hboo.ch the value is defined

#define HB_OO_CLSTP_EXPORTED 1 /* No comment, default */

But I don´t find HB_OO_MSG_CLSACCESS, maybe it´s only in the last version of xHarbour

[Antonio Linares]

Stefan,

It is a Harbour value, if does not exist in xharbour.
Maybe there is an equivalent value in xHarbour, I have not checked it.

You can review the source code of rtl\TClass.prg to see the way that the Harbour Classes engine adds new ClassDatas.

[Antonio Linares]

I want to clearify that I fully agree with Stefan that the right way is to inherit a new Class and modify it properly.

The published function is just an easy and quick way to test it, for Dutch requirement. That code may change and may not work in the future, etc. as it is highly based on Harbour internals.

[Adolfo]

Adolfo,

You can do it this way:

Code: Select all  Expand view

   TGet():SetColorFocus( nRGB( 200, 120, 120 ) )
 

Please notice that we don't really create a GET control, as we don't call New() or Redefine() methods

Antonio.
Works Great

Thanks
Adolfo