CLASS TBitmap ( Solved )

[lailton.webmaster]

HI,
SOmeone can help me with this,
How add method OnMouseOver and OnMouseOut to this class;

Thanks.

[Antonio Linares]

Lailton,

Code: Select all  Expand view

#include "FiveWin.ch"

#define TME_LEAVE        2
#define WM_MOUSELEAVE  675

function Main()

   local oWnd, oBmp

   DEFINE WINDOW oWnd

   oBmp = TMyBitmap():New( 50, 50,,,, "test.bmp", .T., oWnd,,,,,,,,, .T. )  
   
   oBmp:bMMoved = { || oWnd:SetText( "Over me" ), TrackMouseEvent( oBmp:hWnd, TME_LEAVE ) }

   oBmp:bMLeave = { || oWnd:SetText( "Out of me" ) }
 
   ACTIVATE WINDOW oWnd

return nil

CLASS TMyBitmap FROM TBitmap

   DATA   bMLeave

   METHOD HandleEvent( nMsg, nWParam, nLParam )

   METHOD MouseLeave( nRow, nCol, nFlags )
   
ENDCLASS

METHOD HandleEvent( nMsg, nWParam, nLParam ) CLASS TMyBitmap

   if nMsg == WM_MOUSELEAVE
      return ::MouseLeave( nHiWord( nLParam ), nLoWord( nLParam ), nWParam )
   endif
   
return Super:HandleEvent( nMsg, nWParam, nLParam )      

METHOD MouseLeave( nRow, nCol, nFlags ) CLASS TMyBitmap

   if ! Empty( ::bMLeave )
      Eval( ::bMLeave, nRow, nCol, nFlags, Self )
   endif  

return nil
 

[lailton.webmaster]

Antonio,

It´s work FINE !!!!

Gracias.